暗号入門 - Perlで暗号化

Profile

KENT。KentWeb主催者。
初心者による初心者のための
Perl暗号入門ページです。

目 次

0. はじめに/目次
1. 暗号化の基本
2. 関数 - DES編
3. 関数 - MD5編
4. 関数 - DES/MD5共通編
5. Digest::MD5編
6. サムチェック編
7. Digest::SHA1編
8. Crypt::SaltedHash編
9. Crypt::Blowfish_PP編
10. Crypt::RC4編

注目サイト

W3C標準

Digest::MD5、Digest::SHA-1の2つを解説して、暗号・照合のコード例を書いたところで、saltを自動的に付加して暗号化し、さらに照合する関数まで持ったPerlモジュールが存在していることを知りました。オーノーであります。

8-1. デモ

8-2. Crypt::SaltedHashモジュール

use Crypt::SaltedHash;

my $csh = Crypt::SaltedHash->new(algorithm => 'SHA-1');
$csh->add('secret');

my $salted = $csh->generate;
my $valid = Crypt::SaltedHash->validate($salted, 'secret');

8-3. 暗号と照合

use strict;

# モジュールを宣言
use Crypt::SaltedHash;

# 文字列
my $passwd = 'password';

# オブジェクト定義
my $csh = Crypt::SaltedHash->new();
$csh->add($passwd);

# 暗号化
my $crypt = $csh->generate;
print "$crypt\n";

>  {SSHA}Z0a89YcM7fV4Pxl7wkF+3+7y/b4cxFb/

use strict;

# モジュールを宣言
use Crypt::SaltedHash;

# 文字列
my $passwd = 'password';

# オブジェクト定義 + オプション指定
my $csh = Crypt::SaltedHash->new(
		algorithm => 'MD5',  # MD5形式
		salt_len  => 8,      # salt文字数
	);
$csh->add($passwd);

# 暗号化
my $crypt = $csh->generate;
print "$crypt\n";

>  {SMD5}J1QGWc5/ARLOqgLarLbRYBjKZ9d4GAVv

Crypt::SaltedHash->validate('暗号文字列', 'パスワード');

use strict;

# モジュールを宣言
use Crypt::SaltedHash;

# 文字列
my $passwd = 'password';

# 暗号文字
my $crypt = '{SSHA}Z0a89YcM7fV4Pxl7wkF+3+7y/b4cxFb/';

# 判定
my $valid = Crypt::SaltedHash->validate($crypt, $passwd);
if ($valid) {
	print "OK\n";
} else {
	print "NG\n";
}

>  OK

use strict;

# モジュールを宣言
use Crypt::SaltedHash;

# 文字列
my $passwd = 'password';

# 暗号
my $crypt = &encrypt($passwd);
print "$crypt\n";

# 照合
if (Crypt::SaltedHash->validate($crypt, $passwd)) {
	print "OK\n";
} else {
	print "NG\n";
}

#-----------------------------------------------------------
#  Crypt::SaltedHash暗号
#-----------------------------------------------------------
sub encrypt {
	my $plain = shift;

	# オブジェクト定義
	my $csh = Crypt::SaltedHash->new();
	$csh->add($plain);

	# 暗号化
	return $csh->generate;
}

>  {SSHA}DW9lZwVZMu0sN6VK5q6asPthnzv1LMuS
>  OK

8-4. 【コラム】Perlモジュールの組み込み

/homepage
   |
   +-- cgi / crypt.cgi ← CGIプログラム
        |
        +-- lib / Foo.pm ← ここに置く（Fooモジュール）

use lib "./lib";
use Foo;

/homepage
   |
   +-- cgi / crypt.cgi ← CGIプログラム
        |
        +-- lib /
             |
             +-- Foo / Bar.pm ← ここに置く（Foo:Barモジュール）

use lib "./lib";
use Foo::Bar;

(2) モジュールの入手方法
Perlモジュールは、cpanにアップロードされていますので、検索してダウンロードします。
cpanとは、世界中のほとんどのPerlモジュールがアップされているライブラリで、利用者は自由にダウンロードすることができる場です。

http://www.cpan.org/

本章のCrypt::SaltedHashは、以下にあります。

http://search.cpan.org/~gshank/Crypt-SaltedHash-0.09/

Downloadをクリックすると、書庫ファイル（tar.gz圧縮されています）がダウンロードが開始されます。
また、Browseをクリックすると、任意のファイルを個別にダウンロードすることができます。

tar.gzファイルは、UNIX形式の書庫ファイルですが、以下のツール（どちらでもよい）を使用することで、Windowsでも解凍することができます。

Lhaplus     +Lhaca

tar.gzファイルをダウンロードし、解凍した場合には、諸々のファイルが同梱されていますが、必要なのは、.pmファイルです。
Crypt::SaltedHashの場合だと、lib/Crypt/SaltedHash.pmがそれに当ります。

/homepage
   |
   +-- cgi / crypt.cgi ← CGIプログラム
        |
        +-- lib /
             |
             +-- Crypt / SaltedHash.pm ← ここに置く（Crypt::SaltedHashモジュール）

CGIプログラム側からのコールは、次のように記述します。

use lib "./lib";
use Crypt::SaltedHash;